為一批word統一加文件名字

『壹』 word文件怎麼批量改名

批量修改word文件名稱的方法：

步驟1，下載工具軟體後安裝打開，如下圖所示點擊任意一個紅框，將需要修改名稱的word文件添加到軟體中，可以從不同文件夾中添加哦！

『貳』 如何批量在word文檔里添加當前文件名。

1.打開WinRAR。隨便打開一個壓縮文件，然後向上返回即可；或雙擊打開WinRAR.exe。
2.在WinRAR的資源管理界面上，到達你所要復制的文件名的根目錄下(以下以系統盤C：為例)

3.Ctrl+A（全選）

4.右鍵，將剛才全選的文件選擇「添加文件到壓縮文件中」，然後會跳出一個新窗口。

5.在跳出的新窗口中，點擊選擇「文件」的選項卡。
6.你將發現在「要添加的文件」里，有很多的文件名，這些文件名是已經被選中的，而且用空格以及雙引號分開的，復制（Ctrl+C）它們。 7.打開記事本或UltraEdit等文本編輯器，粘貼(Ctrl+V)。 8.這時，剛才復制的文件名會全部列出來，然後你就可以慢慢將文件名前後的雙號去掉，並進行一些整理。 9.處理完畢。

『叄』 求救：word批量命名：用word內容首行命名！

你好，批量給文件命名需要藉助相關工具進行，具體操作如下：

1、點擊添加文件把我們的文件一一添加進來。

『肆』 怎麼批量把word的「標題」設置成為「文件名」

VBS加工
代碼如下所示

選項顯式
錯誤繼續下一步「避免程序崩潰的容錯語句」。重命名的文件可能已經存在。忽略錯誤。

Dim fso，fs，f
創建相應的變數
Dim strNewName
Const strCurrentPath = "，"

Msgbox "根據文本文件的第一行批量重命名VBS程序"

『伍』 如何快速給大量word文件重命名

可以用腳本來做。

1、用記事本新建一個文本文件，把它保存為「批量重命名.vbs」（注意不要弄成了「批量重命名.vbs.txt」，也就是要確保其擴展名為「.vbs」）；
2、把下列代碼粘貼到這個VBS文件中：
Option Explicit
Const g_strRootPath = "c:\Temp\docs\Word\ToRename\" ' 指定存放所有文件的目錄，可以有子目錄
Const g_nTitleMaxLen = 16 ' 指定獲取文檔裡面第一段中的前多少個字元來作為文件名
Call Main
' 主函數入口
Sub Main()
Dim fso, oFolder, oWordApp
Set oWordApp = CreateObject("Word.Application")
Set fso = CreateObject("Scripting.FileSystemObject")
Set oFolder = fso.GetFolder(g_strRootPath)
RenameDocFilesUnderFolder oWordApp, fso, oFolder
oWordApp.Quit
Set oWordApp = Nothing
MsgBox "完成！"
end Sub
' 重命名指定文件夾（遞歸）下面的所有Word文件，按照文件裡面的第一句可見的文字命名
Sub RenameDocFilesUnderFolder(oWordApp, fso, oFolder)
Dim oSubFolder, oFile, oDoc
Dim strTitle, strFileName
For Each oSubFolder In oFolder.SubFolders
RenameDocFilesUnderFolder oWordApp, fso, oSubFolder
next
For Each oFile In oFolder.Files
Set oDoc = oWordApp.Documents.Open(oFile.Path)
strTitle = GetFirstVisibleTextContent(oDoc)
oDoc.Close
Set oDoc = Nothing
If Len(strTitle) <> 0 Then
strFileName = fso.BuildPath(fso.GetParentFolderName(oFile.Path), strTitle & "." & fso.GetExtensionName(oFile.Path))
strFileName = GetUniqueFileName(fso, strFileName)
fso.MoveFile oFile.Path, strFileName
end If
next
end Sub
' 獲取指定文檔第一行可見文字
Function GetFirstVisibleTextContent(oDoc)
Dim oParagraph
Dim strContent
For Each oParagraph In oDoc.Paragraphs
strContent = GetSafeFileName(oParagraph.Range.Text)
If Len(strContent) <> 0 Then
GetFirstVisibleTextContent = strContent
Exit Function
end If
next
GetFirstVisibleTextContent = ""
end Function
' 過濾文件名裡面的無效字元
Function GetSafeFileName(strFileName)
Dim arrUnsafeCharacters, strUnsafeChar
Dim nIndex
arrUnsafeCharacters = Array("\", "/", ":", "*", "?", """", "<", ">", "|")
For nIndex = 0 To &H2F
strFileName = Replace(strFileName, Chr(nIndex), "")
next
For Each strUnsafeChar In arrUnsafeCharacters
strFileName = Replace(strFileName, strUnsafeChar, "")
next
GetSafeFileName = left(Trim(strFileName), g_nTitleMaxLen)
end Function
' 獲取不重復的文件名，如果有重名則在文件名後面附加「_1」、「_2」……
Function GetUniqueFileName(fso, strFullName)
Dim strParentFolder, strBaseName, strExtensionName
Dim nIndex
If Not fso.FileExists(strFullName) Then
GetUniqueFileName = strFullName
Exit Function
end If
strParentFolder = fso.GetParentFolderName(strFullName)
strBaseName = fso.GetBaseName(strFullName)
strExtensionName = fso.GetExtensionName(strFullName)
nIndex = 0
While fso.FileExists(strFullName)
nIndex = nIndex + 1
strFullName = fso.BuildPath(strParentFolder, strBaseName & "_" & nIndex & "." & strExtensionName)
Wend
GetUniqueFileName = strFullName
End Function

3、修改代碼中開始部分的兩個設置，即：存放等待重命名的Word文件的根目錄，以及獲取文檔第一段內容時最多保留多少個字元。
4、保存這個VBS文件，在資源管理器中雙擊運行它，直到看見「完成」！
5、檢查所有文件是否已自動重命名。
注意：如果有兩個以上的文檔依據其內容提取出來的文字相同，則會自動在文件名後面附加「_1」、「_2」、「_3」……。

『陸』 office高手 請問如何在所有的excel（或者Word或者ppt文件）文件名字後面統一加上幾個字

可用DOS命令實現。
1、先把所有需要改名的任意文件（包括EXCEL、WORD等，什麼文件都可以）放到一個文件夾，比如D盤下的AAA文件夾。
2、開始——運行——CMD
然後在彈出的DOS窗口輸入：
rename D:\AAA\*.* ?????????????——經理班.*
敲回車即可。
注意DOS窗口下可以按CTRL+空格來切換成中文輸入法。
另外注意一個?號代表一個英文字元的位置，所以如果你有的文件名很長的話，那你的?號就應該有很多個，比如你的文件名有十個中文字，那你的問號就應該要有20個。問號多了不會影響短的文件名，而問號少了那些長文件名就會被截掉後面的，所以盡量多問號吧。

補充：
我重新測試了下，命令沒有問題的，不過原來的一個*號應該改為多個？號。如果你運行命令報錯應該是你沒輸入正確。
請留意rename與D:之間有個空格，*.*與???????????——經理班.*之間也有個空格。
另外除了「——經理班」外，其他字元請在英文模式下輸入。